Si estás leyendo esto es porque ya estás familiarizado con el crowdlending, de hecho estás registrado en una o varias plataformas pero te resulta un poco caótico el seguimiento. No sabes cuánto interés te está dando cada una exactamente (lo que dice la web es teórico) y estás buscando una manera que no implique mucho esfuerzo periódico para poder hacer un seguimiento que te de una idea de qué plataforma es mejor que cual y cuánto estás ganando con cada una de ellas.
En este post te explicaré cómo lo hago yo, y te lo explicaré paso por paso para que puedas realizarlo tú también. Te enseñaré cómo es la hoja de cálculo que utilizo, cómo la utilizo y cómo puedes construirte tú una igual.
¿Cómo usar una hoja de cálculo para llevar el seguimiento de mis plataformas de crowdlending?
La idea es sencilla. Tener un sistema que permita de manera semiautomática tener registrado la evolución de nuestras plataformas de crowdlending. Para ello, la forma más sencilla es utilizar una hoja de cálculo. No requiere conocimientos especiales y está al alcance de cualquier persona.
El proceso utilizado pasa por descargar de cada una de nuestras plataformas un extracto en Excel de los movimientos desde el 1 de enero del año en cuestión hasta el día de hoy. Se abre el documento y se copia ese listado, para a continuación pegarlo en una hoja de nuestra Excel. Mediante las fórmulas definidas se realizan automáticamente todos los cálculos, y nos aparecen todos los ingresos de la plataforma, con el interés generado por día, mes y año, tanto en euros como en porcentaje.
Repitiendo este proceso en todas nuestras plataformas tendremos un resumen del rendimiento conjunto de todas y desglosado por cada una de ellas. También podemos obtener la cantidad que deberemos tributar a final de año, aunque esto último hay que tomarlo como orientación, pues para la renta es mejor descargar los informes de cada plataforma y declarar eso, que es lo que nos valdrá como justificante si hay una inspección.
Además, este proceso se puede realizar tantas veces como sea necesario a lo largo del año, y siempre es igual, no hay que hacer nada extra entre estas iteraciones.
El aspecto que tiene la hoja de cálculo es el siguiente
En el bloque 1 aparecen desglosados tanto los intereses como las cantidades ganadas mes a mes. En el bloque 2 aparece el interés anual que nos está dando, junto con el equivalente en euros y el porcentaje neto e impuestos. El bloque 3 contiene un desglose día por día de las retiradas e ingresos, intereses puntuales y acumulados. El bloque 4 representa esta información sumada de todas nuestras plataformas, mientras que el bloque 5 corresponde a las pestañas que contienen la información de cada una de ellas.
¿Por qué esta manera de representar los datos?
De esta manera tenemos un resumen de fácil interpretación por plataforma y uno general. Al desglosar cada plataforma en tres pestañas conseguimos que los extractos de cada una de ellas sean directamente copiables en una de ellas, con ninguna o mínimas modificaciones de lo que nos ofrece la exportación (pestaña _src), la pestaña intermedia (_aux) se encarga de formatear y presentar los datos de cada plataforma para que la pestaña resumen (pestaña _total) sea exactamente igual para todas las plataformas. Así pues con estos tres niveles se consigue facilitar el mantenimiento. Hay que tener en cuenta que las plataformas con el tiempo realizan cambios en la estructura de los excels de exportaciones, y seremos nosotros los que tengamos que modificar las fórmulas de la pestaña _aux, pero únicamente tendremos que modificar esta, el resto de cálculos seguirá siendo válido, y podremos seguir haciendo un copiar y pegar de las exportaciones.
Eligiendo las plataformas para realizar el seguimiento
En este post proponemos usar varias plataformas que han aguantando bien la pandemia del covid 19. Las tres ofrecen principal e intereses garantizado. De hecho puedes registrarte a través de estos enlaces y te darán una cantidad debida a la inversión.
- En Twino te darán 20 euros si inviertes al menos 100 euros en la plataforma.
- En Peerberry te darán desde 10 euros si inviertes a partir de 500 euros durante al menos 30 días.
- En Robocash te darán desde 10 euros si inviertes a partir de 500 euros durante al menos 30 días.
Sin embargo puedes encontrar información más extensa sobre la elección de plataformas de crowdlending para inversión en este blog.
Descarga de datos de las plataformas de crowdlending
El ejemplo se va a realizar con Twino, y para el resto de plataformas se especificarán las diferencias. El primer paso será descargar el listado de la cuenta, lo que se suele denominar el «account statement» desde el día 1 de Enero hasta la actualidad. En Twino se realiza de la siguiente manera.
Esto generará un fichero con el nombre account_statement.xlsx. Si a continuación lo abrimos con Microsoft Excel o cualquier otra aplicación que permita visualizar hojas de cálculo veremos un listado como el que hay a continuación.
Hay que fijarse que en este caso al abrir el Excel aparece una columna con almohadillas. Es importante desplazarla para que se pueda visualizar su contenido, pues de no hacerlo, el portapapeles no almacenará bien los datos, y al pegarlos no se podrán pegar correctamente.
Una vez hecho esto, seleccionamos todas las filas y columnas (o bien Control+A o bien pinchando el recuadro que tenemos entre la columna A y la fila 1) y pulsamos copiar (o Control+C).
Nos vamos a nuestra hoja de cálculo en la pestaña denominada twino_src, pulsamos la primera celda y pulsamos edición -> pegar (o Control+V) y acabaremos teniendo el mismo listado del Excel en la hoja de cálculo.
Procesado de los movimientos de la plataforma de crowdlending
Una vez tenemos los movimientos en nuestra hoja de cálculo necesitaremos procesarlos y obtener los ingresos por una parte y el capital por otra. Para ello nos iremos a la pestaña twino_aux y lo dividiremos conceptualmente en tres partes. En la primera haremos un listado de las variaciones de capital (ingresos y retiradas) de la plataforma. En la segunda un listado de ingresos debidos a intereses y bonos. En la tercera haremos una copia de los datos de la pestaña twino_src.
Para todas estas operaciones utilizaremos un lenguaje que proporciona Google Spreadsheets muy similar al SQL, utilizado para la consulta de bases de datos. Este lenguaje proporciona mucha potecia para hacer operaciones con muy poco. Desafortunadamente no es tan potente como el SQL normal, por lo que habrá que añadir alguna columna a mano, y es por esto por lo que haremos aquí esta tercera columna con la copia de twino_src.
Copia de los datos de crowdlending desde el origen de la exportación Excel
Si nos situamos en la casilla I1 podemos hacer fácilmente una copia de la pestaña anterior escribiendo
=QUERY(twino_src!A:F;"select *")
Esto toma de base los datos entre las columnas A-F de la pestaña twino_src y le aplica un «SELECT *». Para más informacion de lo que se puede hacer con este lenguaje consultad la sintaxis del lenguaje SQL.
Los conocedores de este lenguaje, verán que en lugar de la cláusula FROM, se usa el primer argumento de la función QUERY. Únicamente nos quedará transformar la fecha en un número, puesto que actualmente es una cadena de texto con la que no podemos hacer comparaciones. Como no se pueden utilizar funciones de Google Spreadsheet en la cláusula SELECT, habrá que crear una columna extra a mano. Lo haremos en la celda H2, en la que escribiremos
=rounddown(I2)
En la celda H1 escribiremos el título «FECHA» para saber lo que representa, y pulsando la intersección entre la celda H2 y la I3, sin soltar, arrastraremos hacia bajo para copiar esta celda hasta el final de la hoja Excel
Cálculo de los intereses de crowdlending desde la exportación de Excel
Ahora calcularemos los intereses. Nos colocamos en la celda A1 y escribimos
=QUERY(H:N;"select H,sum(N) WHERE L='INTEREST' or L='PENALTY' group by H")
Esto lo que hará es seleccionar la columna que acabamos de crear con la fecha en formato numérico, y la suma de todas aquellas líneas cuya descripción sea del tipo «INTEREST» o «PENALTY»
Ahora dispondremos de un listado agrupado por fecha numérica de todos los intereses generados.
Cálculo de los ingresos y retiradas de crowdlending desde los datos de exportación en Excel
Por último haría falta hacer lo mismo con las retiradas y los ingresos. Para ello nos situaremos en la celda D1 y escribiremos
=QUERY(H:N;"select H,N WHERE K='FUNDING'")
Esto nos generará un listado de aquellos ingresos y retiradas agrupados por fechas también
Con esto tendremos acaba la pestaña de twino_aux y twino_src. Únicamente nos quedará representar estos datos en una tabla
Representar los movimientos de la plataforma de crowdlending
Finalmente vamos a la parte que más interesa que es la presentación final de los resultados. Nos situaremos en la pestaña de twino_total. Allí nos situaremos en la casilla A4 y escribiremos 2020. Esta casilla se utilizará para mostrar las fechas y hará que cuando pasemos de año sea más fácil modificar la hoja.
Representación diaria de los flujos de caja de mis plataformas de crowdlending
Situándonos en la casilla A9 escribiremos
=DATEVALUE($A$4&"/1/1")+row()-9
Esto lo que hace es coger el valor del año que hemos cogido en la celda A4, lo fijamos con el «$» para que no se modifique cuando copiemos y peguemos la celda, le añadimos /1/1 (con lo que queda la cadena «2020/1/1», lo transformamos en número (como los que habíamos generado antes en twino_aux), le sumamos la fila actual (en este caso un 9) y le restamos 9 (porque estamos en la fila 9. Con esto nos aparecerá un 42370. Si pulsamos en la celda para seleccionarla y elegimos en el menú Formato->Número -> fecha, visualizaremos dicho número como «1/1/2020»
Si a continuación pulsamos en la intersección entre la casilla A9 y la B10 y arrastramos sin soltar hacia bajo, irán apareciendo todas las fechas del año 2020, una por celda. Lo haremos hasta el 31 de Diciembre de 2020.
En la casilla A7 añadiremos «Periodo actual» y en la A8 «Fecha»
En la casilla B9 escribiremos lo siguiente
=if(isna(VLOOKUP(rounddown(A9);twino_aux!D$1:F$1000;2;FALSE));0;VLOOKUP(rounddown(A9);twino_aux!D$1:F$1000;2;FALSE))
Esta fórmula es un poco más compleja. Lo que hace es lo siguiente:
- buscar mediante la función VLOOKUP el valor de la celda comprendida entre la casilla D1 y D1000 de la pestaña twino_aux que se corresponda con la fecha de la fila en la que se encuentra la fórmula, en este caso en la A9
- Evalua condicionalmente este resultado, de manera que si es un error, en la casilla B9 se mostrará un 0, y si no lo es, se mostrará el valor correspondiente a la casilla en la que se ha encontrado el valor en twino_aux +2, resultando ser la cantidad añadida o retirada para esa fecha
Sólo queda arrastrar esa celda para hacer que llegue hasta el 31 de Diciembre de 2020, de igual manera que se ha hecho anteriormente con las propias fechas.
Escribiremos en la celda A5 «periodo anterior», en la B6 «aportaciones» , en la B5 la cantidad que teníamos invertida en 2019, en este caso, como es un ejemplo escribiremos 300 (este dato no se usa en los cálculos posteriores, es meramente informativo) y en la casilla B7 la fórmula
=sum(B8:B375)
Con esto estaremos calculando en esta celda la cantidad invertida en la plataforma durante este año, es decir, las diferencias entre ingresos y retiradas
Para calcular los intereses nos colocaremos en la celda D9 y escribiremos la siguiente fórmula
=if(isna(VLOOKUP(rounddown(A9);twino_aux!$1:$1000;2;FALSE));0;VLOOKUP(rounddown(A9);twino_aux!$1:$1000;2;FALSE))
Esta fórmula es idéntica a la anterior con la salvedad de que la tabla de datos sobre la que se calcula es toda la hoja de la pestaña twino_aux ($1:$1000). Por tanto, al sumarle 2, nos estamos refiriendo a la columna de ingresos agrupados por día.
Arrastramos hasta llegar igual que antes al 31 de Diciembre y escribimos en las celdas D5, D6 y D7: «intereses», «del» y «día» respectivamente.
A continuación generaremos la columna que muestra los intereses acumulados. Para ello nos situaremos en la celda E9 y escribiremos
=sum(D$9:D9)
Aquí se hace una suma desde la celda D9 fifada (El $ fija la fila 9 para que al arrastrar no se modifique) hasta la celda D9 sin fijar, de manera que si arrastramos como anteriormente hasta la celda del 31 de Diciembre obtendremos todos los intereses acumulados. Además escribiremos en las celdas E5, E6 y E7 las palabras «Acumulado», «intereses», «generados»
Ahora generaremos la columna del saldo en cuenta. Para ello nos colocaremos en la columna C5 la cantidad que teníamos en cuenta el año anterior. En este caso y para que se vea el aumento, colocaremos 1000. Nos iremos a la celda C9 y escribiremos:
=sum(B$9:B9)+E9+$C$5
Esto lo que hará será sumar todas las aportaciones desde el 1 de Enero hasta la fila en la que se está calculando (sum(B$9:B9)) al interés acumulado para esta misma fila (E9) más la cantidad que teníamos el año anterior ($C$5, en este caso fijamos tanto la fila como la columna con el $ para que al arrastrar este valor no cambie). Arrastramos hasta la fila del 31 de Diciembre, escribirmos en la fila C6 «saldo en cuenta» y en la C7 escribimos
=C374
Esto último muestra el saldo actual, que si están actualizados los datos será igual al que la hoja muestre el día 31 de Diciembre.
Finalmente sólo quedan las columnas de los porcentajes. Nos situamos en la F9 y escribimos
=D9/C$7
Si pulsamos sobre ella y acudimos a Formato -> Número -> porcentaje obtendremos el valor representado como porcentaje
Arrastramos una copia de esa celda hasta la fila del 31 de Diciembre y escribimos en las casillas F5, F6 y F7 respectivamente «% interés», «del», «día».
La última columna representa el % de interés acumulado. Para ello lo que habrá que hacer es sumar desde la fila en cuestión hacia atrás. Escribiremos la siguiente fórmula en la casilla G9
=sum($F$9:F9)
Esta fórmula tiene la misma explicación que la columna E. Arrastraremos esta casilla hasta la fila del 31 y de Diciembre y escribiremos en las casillas G5, G6 y G7 respectivamente «Acumulado», «% interés», «generado»
Representacion mensual de los inereses de mis plataformas de crowdlending
El siguiente elemento a representar es la tabla resumen mes a mes. Para ello nos situaremos en la celda B2 y escribiremos «Enero», continuaremos con la C2 hasta la M2 escribiendo en orden el resto de meses que quedan hasta «Diciembre». En las celdas N2, O2 y P2 escribiremos respectivamente «TOTAL», «total neto» e «impuestos»
Ahora que tenemos la cabecera de la tabla, vamos a rellenarla. En la celda B3 escribiremos
=VLOOKUP(ROUNDDOWN("31/1/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/1/"&$A$4);$A:$G;7)
Esto lo que hace es crear una cadena de caracteres con las fechas 1 de Enero de 2020 y 31 de Diciembre de 2020, obotener el código numérico de esas fechas, buscar el valor de la columna G (argumento «;7)» de la función) que corresponde al interés acumulado y restarlo. Con esto obtendremos el interés acumulado del mes de Enero. Se concatena así, para que al cambiar de año lo único que haya que hacer es poner en la casilla A4 un 2021 y el resto de fórmulas no habrá que tocarlas. Para los siguientes meses no basta con copiar y arrastrar esta vez, hay que especificar las fórmulas una por una. A continuación las fórmulas para las casillas desde la C3 hasta la M3:
=VLOOKUP(ROUNDDOWN("29/2/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/2/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/3/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/3/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("30/4/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/4/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/5/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/5/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("30/6/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/6/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/7/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/7/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/8/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/8/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("30/9/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/9/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/10/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/10/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("30/11/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/11/"&$A$4);$A:$G;7)
=VLOOKUP(ROUNDDOWN("31/12/"&$A$4);$A:$G;7)-VLOOKUP(ROUNDDOWN("1/12/"&$A$4);$A:$G;7)
La celda N3 representa el % de interés anual ganado hasta el momento. Para este cálculo bastará con sumar todos los intereses desde enero hasta diciembre.
=sum(B3:M3)
El total neto y los impuestos serán la casilla que se acaba de calcular multiplicado por 0,81 para el total neto y por 0,19 para los impuestos, suponiendo un tipo impositivo del 19%
=$N3*0,81 =$N3*0,19
Por último queda la fila de las ganancias mensuales. Este cálculo es parecido al anterior. De hecho la única diferencia es que se coge la columna E en lugar de la G como antes, para ello lo único que habrá que hacer es reemplazar el 7 por el 5. Para ello, seleccionando de la celda B3 a la M3 copiamos esas celdas de la fila 3 a la 4. Editaremos una por una y modificaremos el 7 por el 5 de manera que queden de la siguiente manera
=VLOOKUP(ROUNDDOWN("31/1/"&$A$4);$A:$G;5)-VLOOKUP(ROUNDDOWN("1/1/"&$A$4);$A:$G;5)
Al copiarlas se habrá quedado el formato porcentaje, así que habrá que cambiarlo a moneda. Así que iremos al menú superior de Formato -> Número -> Moneda
Las celdas N4, O4 y P4 serán respectivamente el valor a 31 de Diciembre de los intereses acumulados (=E374), El valor de N4 multiplicado por 0,81 (=$N4*0,81) y el varlor de N4 multiplicado por 0,19. Todo esto en formato moneda también.
Para darle el último toque, dibujaremos los contornos de la tabla superior. Para ello seleccionaremos desde la celda B2 hasta la celda M4 y pulsaremos el icono de bordes exteriores
Como última línea de contorno, seleccionaremos desde la celda B2 hasta la celda P2 y seleccionaremos
Hasta aquí hemos construido las tres pestañas para la plataforma twino. Aunque no se va a desarrollar en este post, es posible hacer otras tres pestañas por cada plataforma que tengamos, siguiendo la misma estrategia y luego una única pestaña denominada «TOTAL» que totalice los resultados. Ésta será igual que twino_total, pero cada casilla será la suma de esa misma casilla en twino_total y el resto de pestañas cuyo nombre acabe en «_total».
Cómo interpretar los resultados de la plataforma de crowdlending
Para interpretar los datos únicamente nos fijaremos en twino_total. Lo más interesante es ver la columna N, donde podemos ver el rendimiento real de la plataforma hasta el momento, tanto porcentualmente como en euros. Hay que tener en cuenta que estas plataformas no retienen impuestos, por tanto, presuponiendo como en este ejemplo una tasa impositiva del 19%, podemos ver en la columna O los datos después de impuestos.
Tenemos el detalle mes a mes en la tabla B2:M4. Es aquí donde se puede realizar un seguimiento más exhaustivo y hacer una comparativa entre nuestras plataformas. Por ejemplo un 1% porcentual en un mes implica un 12% anualizado, que es una cifra común a día de hoy en nuestras plataformas, por tanto, si vemos que durante varios meses obtenemos menos de esa cifra cuando la plataforma prometía esta cantidad o bien el interés es más bajo del que realmente ofrecen, o bien no tenemos bien configurada la plataforma. De cualquier manera, es en estos casos cuando tendremos que revisar nuestra configuración para detectar posibles problemas. Si por otra parte se mantiene rondando el 1% o superior, esta plataforma no requiere nuestra atención.
Si queremos hilar más fino, podemos acudir a la tabla diaria (A:9:G374), donde podemos ver el flujo de ingresos de la plataforma. Aquí veremos los días en los que tarda en realizar los reintegros, lo que tarda en reconocer un ingreso (sabiendo qué día hemos realizado la orden en nuestro banco, claro. Lo interesante es que de un vistazo rápido podemos ver cualquier anomalía, puesto que lo normal es que los numeros sean muy parecidos entre unos días y otros.,
Finalmente en la tabla B5:C7 podemos ver cuánto hemos invertido este año, y la cantidad total de dinero que tenemos en la plataforma. Con toda esta información podemos tomar decisiones como si debemos rebalancear la plataforma o si los resultados que está dando son los esperados.
De igual manera, podemos ver la pestaña «TOTAL» de plataformas estos mismos valores. Aquí no podemos deducir qué plataformas van bien o mal. Aquí veremos cómo de rentable es nuestra inversión en crowdlending.